supermanoeuvre

Living Morphologies – Housing Precedent Lists

iainmaxwell — Wed, 01 Sep 2010 11:01:53 +0000

Habitat ‘67 (1967), Moshe Safdie, Montreal, Canada
Mountain Dwellings (2008), Bjarke Ingels Group, Ørestad
Mirador Housing (2005), MVRDV, Madrid, Spain
Gifu Kitagata Housing (2000), SANAA, Gifu, Japan
Eda Apartments (2002), SANAA, Kanagawa, Japan.
Unité d’Habitation (1952), Le Corbusier, Marseille, France
Walden 7 (1974), Ricardo Bofil, Barcelona, Spain
Kanchanjunga Apts (1983), Charles Correa, Mumbai, India
Maharashtra Housing (1999), Charles Correa,Maharashtra, India
Indian Institute of Management (1962), Louis I. Kahn, Ahmedhabad, India
MIT Simmons Hall (2004), Steven Holl, Boston, USA
Fukuoka Housing (1991), Steven Holl, Fukuoka, Japan
Barcom Avenue Housing (2004), Engelen Moore, Darlinghurst, Sydney
Rue des Suisses (2000), Herzog & de Meuron, Paris, France
Ivry Sur Seine (1980), Jean Renaudie, Paris, France
Trellick Tower (1972), Erno Goldfinger, London, U.K.
Baumhaus in Helmond (1984), Piet Blom, Rotterdam, The Netherlands.
Nexus World Housing (1991), OMA, Fukuoka, Japan.
Carabanchel Apartments (2007), Dosmasuno Arquitectos, Madrid, Spain.
Carabanchel Apartments (2007), Foreign Office Architects (FOA), Madrid, Spain.

Geometric Transformations

iainmaxwell — Tue, 31 Aug 2010 10:47:32 +0000

Using Orient 3D

 
Option Explicit
'Script written by maxi
' do this to a welded mesh box

Call Main()
Sub Main()
 
	'------------------------------------------------------------------
	'USER INPUTS
	Dim strStartObj : strStartObj =  rhino.getObject("gimme BOX", 32)
	If isNull(strStartObj) Then Exit Sub
 
	'------------------------------------------------------------------
	'SCRIPT	
	' get the vertices of the welded mesh object
	Dim arrVertices : arrVertices = Rhino.MeshVertices (strStartObj) 
 
	' apply a orient3D and copy!
	Dim arrPlaneStart   : arrPlaneStart   = Array( arrVertices(0), arrVertices(2) )
	Dim arrPlaneTargets : arrPlaneTargets = Array( Array(arrVertices(3), arrVertices(7)),  Array(arrVertices(2), arrVertices(5)) )	
 
	Dim i
	For i =0 To ubound(arrPlaneTargets)
		Call rhino.OrientObject(strStartObj, arrPlaneStart, arrPlaneTargets(i), 1+2)
	Next	
 
End Sub

Attractor Based Transformations

 
Option Explicit
'Script written by maxi@supermanoeuvre.com

Call Main()
 
Sub Main()
 
	'----------------------------------------------------------
	' USER INPUTS
	Dim strMesh : strMesh = rhino.getObject("gimme MESH", 32)
	If isNull(strMesh) Then Exit Sub
 
	Dim strAtts : strAtts = rhino.getObjects("gimme attractor POINT objects", 1)
	If isNull(strAtts) Then Exit Sub
 
	Dim dblAttractionScale : dblAttractionScale = 50.0
 
	'----------------------------------------------------------
	' SCRIPT PROPER
	
	Dim arrMeshVerts : arrMeshVerts = rhino.MeshVertices(strMesh)
	Dim arrMeshFaces : arrMeshFaces = Rhino.MeshFaceVertices(strMesh)
 
	Dim i
	Dim arrPtClosestAtt, arrVecBetween, dblLen
	Dim arrVecNorm, arrVecScaled, arrPtNew
	Dim arrNewMeshVerts()
 
	For i = 0 To ubound(arrMeshVerts)
		' find the closest attractor
		arrPtClosestAtt = getClosestAttractorLocation(arrMeshVerts(i), strAtts)
		' make a vector between current location and attractor
		arrVecBetween   = rhino.VectorSubtract(arrPtClosestAtt, arrMeshVerts(i))		
		' Do some scaling based on distance, etc....
		dblLen          = rhino.vectorLength(arrVecBetween)
		arrVecNorm      = Rhino.VectorUnitize(arrVecBetween)
		arrVecScaled    = rhino.VectorScale( arrVecNorm, (1/dblLen) * dblAttractionScale )
		' move back relatice to starting position
		arrPtNew        = rhino.pointAdd(arrVecScaled, arrMeshVerts(i))
		ReDim Preserve arrNewMeshVerts(i)
		arrNewMeshVerts(i) = arrPtNew
	Next
 
	Call rhino.AddMesh(arrNewMeshVerts, arrMeshFaces)
 
End Sub
 
Function getClosestAttractorLocation(TESTPT, STRATTS)
 
	getClosestAttractorLocation = Null
 
	Dim i
	Dim arrPtTest, distClosest, arrPtClosest, distBetween
 
	distClosest = 99999999
 
	For i = 0 To ubound(STRATTS)
		arrPtTest   = rhino.PointCoordinates(STRATTS(i))
		distBetween = rhino.Distance(arrPtTest, TESTPT)
		If distBetween < distClosest Then
			distClosest  = distBetween
			arrPtClosest = arrPtTest
		End If
	Next
 
	getClosestAttractorLocation = arrPtClosest
 
End Function

Transformation Axis

 
Option Explicit
 
Call Main()
 
Sub Main()
 
	'---------------------------------------------------------------------
	' USER INPUTS
	Dim strObj : strObj = rhino.getObject("gimme POLYSURFACE primitive", 4+8+16)
	If isNull(strObj) Then Exit Sub
 
	Dim strAxisCrv : strAxisCrv = rhino.GetObject("gimme axis CURVE", 4)
	If isNull(strAxisCrv) Then Exit Sub
 
	Dim numGens : numGens = 6 
 
	'---------------------------------------------------------------------
	' SCRIPT BODY
	
	'------------------- DEFINE THE ROTATION AXIS
	Dim arrAxis01Start : arrAxis01Start = rhino.CurveStartPoint(strAxisCrv)
	Dim arrAxis01End   : arrAxis01End   = rhino.CurveEndPoint(strAxisCrv)
 
	'------------------- DEFINE THE ROTATION PARAMETER
	Dim arrAxis01      : arrAxis01   = rhino.VectorSubtract(arrAxis01End, arrAxis01Start)
	Dim dblRotParam    : dblRotParam = 360/numGens
 
	'------------------- PERFORM THE ROTATIONS
	Dim i
	For i = 1 To numGens
		Call rhino.RotateObject(strObj, arrAxis01Start, i*dblRotParam, arrAxis01, True)
	Next	
 
End Sub

Quickstart Introduction to Rhinoscript

iainmaxwell — Tue, 31 Aug 2010 10:19:16 +0000

EXERCISE 01: Variables & Data Types

 
Option Explicit
 
Call Main()
 
Sub Main()
 
	' DATA TYPES AND VARIABLES
	
	' INTEGER -- whole numbers!
	Dim intNumber    : intNumebr    = 100
	Dim intNegNumber : intNegNumebr = -154
 
	' DOUBLE or FLOAT or REAL -- precision
	Dim dblValue    : dblValue    = 5.0234
	Dim dblNegValue : dblNegValue = -1753.0234
 
	' STRING -- no mathematical function can be performed on a string!
	Dim strName1 : strName1 = "MAX"
	Dim strName2 : strName2 = "max2x0011xx$%0011"
 
	' BOOLEAN - TRUE or FALSE
	Dim blnAnswer : blnAnswer = True
	Dim blnAnswer : blnAnswer = False	
 
End Sub

EXERCISE 02: Custom Functions

 
Option Explicit
 
Call Main()
 
Sub Main()
 
	' SOME RHINO FUNCTIONS 
	Call rhino.print("hello world")                          ' simple print statement 
	Call rhino.AddSphere( Array(0,0,0), 10 )                 ' a sphere 
	Call rhino.addPoint( Array(rnd*100,rnd*100, rnd*100) )   ' a point randomly in space
		
	' SOME RHINO FUNCTIONS USED TO ASSIGN A VARIABLE
	Dim strMyShape	
	strMyShape = rhino.AddSphere( Array(25,25,0), 25 )
 
	Call rhino.print("The rhino object identifier of strMyShape is " + strMyShape)	
 
	' OUR FIRST CUSTOM FUNCTION
	Dim intMyAge    : intMyAge    = 34
	Dim dblMyHeight : dblMyHeight = 1.85
	Dim dblResult   : dblResult   = customTransformation(intMyAge, dblMyHeight)
	Call rhino.print( "The result of my age multiplied by my height is " + CStr(dblResult) )
 
End Sub
 
 
Function customCalculator(VAL00, VAL01)
 
	customCalculator = Null
 
	Dim answer
 
	answer = VAL00 + VAL01
 
	customCalculator = answer
 
End Function
 
 
Function customTransformation(VAL00, VAL01)
 
	customTransformation = Null
 
	Dim answer
 
	answer = 1 / Sqr(VAL00 + VAL01)
 
	customTransformation = answer
 
End Function

EXERCISE 03: Iteration

 
Option Explicit
 
Call Main()
 
Sub Main()
 
	' A simple loop
	Dim i
	For i = 0 To 10
		Call rhino.print("number " & i & " says hello!")
	Next
 
End Sub

EXERCISE 04: Basic Geometry — Iterative object copying

 
Option Explicit
 
Call Main()
Sub Main()	
 
	'-----------------------------------------------------------
	' USER INPUT	
	
	' WHAT TO COPY?
	Dim strBox : strBox = rhino.getObject("gimme BOX dude", 16) 
	If isNull(strBox) Then Exit Sub
 
	' HOW MANY TO MAKE?
	Dim numBoxes : numBoxes = 10
 
	' HOW FAR TO MOVE?
	Dim dblTransation : dblTransation = 10
 
	'-----------------------------------------------------------
	' SCRIPT ROUTINE
	Dim i
	For i = 0 To numBoxes
		Call rhino.copyObject( strBox, Array(0,0,0), Array(0,0,i*dblTransation) )
	Next
 
End Sub

EXERCISE 05: Basic Geometry — Iterative Geometric Transformations

 
Option Explicit
 
Call Main()
 
Sub Main()	
 
	'-----------------------------------------------------------
	' USER INPUT	
	
	' WHAT TO COPY?
	Dim strBox : strBox = rhino.getObject("gimme BOX dude", 16) 
	If isNull(strBox) Then Exit Sub
 
	' HOW MANY TO MAKE?
	Dim numBoxes : numBoxes = 10
 
	' HOW FAR TO MOVE?
	Dim dblTransation : dblTransation = 10
 
	' HOW MUCH TO ROTATE NEW BOX BY?
	Dim dblRotVal : dblRotVal = 5
 
 
	'-----------------------------------------------------------
	' SCRIPT ROUTINE
	Call rhino.enableRedraw(False)
 
	Dim i
	Dim strNewBox
 
	For i = 0 To numBoxes
		strNewBox = rhino.copyObject( strBox, Array(0,0,0), Array(0,0,i*dblTransation) )
		Call rhino.RotateObject( strNewBox, Array(0,0,0), i*dblRotVal )
	Next
 
	Call rhino.enableRedraw(True)
 
End Sub

EXERCISE 06: Arrays (Part 01 — Static Array lists)

 
Option Explicit
 
Call Main()
 
Sub Main()
 
	Dim arrShoppingList : arrShoppingList = Array("Milk", "Eggs", "Bread", "Chocolate", "Ham")
 
	Dim i
	For i = 0 To ubound(arrShoppingList)
		Call rhino.Print( "Item number " & i & " is " & arrShoppingList(i) )
	Next
 
	Call rhino.Print( "result is " & getItem(arrShoppingList, 3) )
 
End Sub
 
 
Function getItem(ByVal LIST, ByVal INDEX)
 
	getItem = null
 
	Dim result : result = LIST(INDEX)
 
	getItem = result
 
End Function

EXERCISE 07: Arrays (Part 02 — Two-Dimensional Arrays)

 
Option Explicit
 
Call Main()
 
Sub Main()
 
	' AN ARRAY OF STRINGS
	Dim arrGroceryList  : arrGroceryList  = Array("Milk", "Eggs", "Bread", "Chocolate", "Ham")
 
	' ANOTHER ARRAY OF STRINGS
	Dim arrWishList     : arrWishList     = Array("Car", "Boat", "Aeroplane", "Jacket", "Holiday")
 
	' A TW-DIMENSIONAL ARRAY OF STRINGS
	Dim arrCombinedList : arrCombinedList = Array(arrGroceryList, arrWishList)
 
 
	Call rhino.Print( "grocery list result is " & arrGroceryList(3) )
 
	Call rhino.Print( "wish list result is " & arrWishList(0) )
 
	Call rhino.Print( "two-dimensional array result is " & arrCombinedList(0)(3) )	
 
End Sub

EXERCISE 08: Arrays (Part 03A — Dynamic Arrays and Iteration)

 
Option Explicit
'Script written by maxisupermanoeuvre.com

Call Main()
Sub Main()
 
	' LOOP TO BUILD SOME NEW OBJECTS
	Dim i, arrStrObjs()
	For i = 0 To 99
		ReDim Preserve arrStrObjs(i)
		arrStrObjs(i) = rhino.addPoint( Array(rnd*100,rnd*100,rnd*100) )
	Next
 
	' LOOP TO GET CLOSEST POINT && MAKE A LINE
	Dim arrPtCoord, arrPtOther
	For i = 0 To ubound(arrStrObjs)
		arrPtCoord = rhino.PointCoordinates(arrStrObjs(i))
		arrPtOther = getClosestPoint(arrPtCoord, arrStrObjs)
		Call rhino.addLine( arrPtCoord, arrPtOther )
	Next
 
End Sub
 
Function getClosestPoint(TESTPT, PTS)
 
	getClosestPoint = Null
 
	Dim arrPtClosest
	Dim d2,distClosest
	Dim arrPtCoord
 
	distClosest = 99999999
 
	Dim i
	For i = 0 To ubound(PTS)
		arrPtCoord = rhino.PointCoordinates(PTS(i))
		d2 = rhino.Distance(TESTPT, arrPtCoord)
		If (d2 > 0) And (d2 < distClosest) Then
			distClosest  = d2
			arrPtClosest = arrPtCoord
		End If
	Next
 
	getClosestPoint = arrPtClosest
 
End Function

EXERCISE 09: Arrays (Part 03B — Dynamic Arrays and Iteration)

 
Option Explicit
'Script written by maxi@supermanoeuvre.com

Call Main()
Sub Main()
 
	' LOOP TO BUILD SOME NEW OBJECTS
	Dim i, arrStrObjs()
	For i = 0 To 99
		ReDim Preserve arrStrObjs(i)
		arrStrObjs(i) = rhino.addPoint( Array(rnd*100,rnd*100,rnd*100) )
	Next
 
	' LOOP TO GET CLOSEST POINT && MAKE A LINE
	Dim j,k
	Dim arrPt, arrPtOthers
	For j = 0 To ubound(arrStrObjs)
		arrPt       = rhino.PointCoordinates(arrStrObjs(j))
		arrPtOthers = getAllPointsInRange(arrPt, arrStrObjs, 35.0)
		For k = 0 To ubound(arrPtOthers)
			Call rhino.addLine( arrPtOthers(k), arrPt )
		Next
	Next
 
End Sub
 
Function getAllPointsInRange(TESTPT, PTS, RANGE)
 
	getAllPointsInRange = Null
 
	ReDim arrPtsList(-1)
	Dim successCounter, arrPtCoord, d2
 
	successCounter = 0
 
	Dim i
	For i = 0 To ubound(PTS)
		arrPtCoord = rhino.PointCoordinates(PTS(i))
		d2 = rhino.Distance(TESTPT, arrPtCoord)
		If (d2 > 0) And (d2 < RANGE) Then
			ReDim Preserve arrPtsList(successCounter)
			arrPtsList(successCounter) = arrPtCoord
			successCounter = successCounter + 1
		End If
	Next
 
	getAllPointsInRange = arrPtsList
 
End Function

Computing Growth and Aggregation — Lindenmayer Sytems (LSystems)

iainmaxwell — Tue, 31 Aug 2010 09:52:11 +0000

Growth and Aggregation via Lindenmayer Rule-based System

STEP 01: String Substitution
A simple string substitution system. We will hard-code the substitution rules, and draw simple rhino text dots at the locations of the new aggregated cells.

 
Option Explicit
'Script written by maxisupermanoeuvre.com

Call LSystemAggregation()
 
Sub LSystemAggregation()
 
	' USER INOUTS
	Dim numGenerations : numGenerations = rhino.getInteger("How many GENERATIONS to run?", 5)
	Dim strInput       : strInput       = rhino.GetString("gimme starting STRING input", "A")
	Dim dblOffset      : dblOffset      = 5
 
	Call computeLSystem(strInput, numGenerations, dblOffset)
 
 
End Sub
 
'-----------------------------------------------CUSTOM RECURSIVE FUNCTION
Function computeLSystem(STRINPUT, GENERATIONS, DISTANCE)
 
	computeLSystem = Null
 
	Dim strStartDot : strStartDot = rhino.addTextDot( STRINPUT, Array(0,0,0) )
	Dim arrDots
 
	' loop for given number of generations
	Dim i		
	For i = 0 To GENERATIONS-1
 
		' each time through create an array list to store all the new dots 
		If i= 0 Then
 
			ReDim arrNewDots(0)
			arrDots = strStartDot		
			arrNewDots(0) = strStartDot		
 
		Else	
 
			arrDots = arrNewDots
			ReDim arrNewDots(-1)		
 
			' loop through characters and apply LSYSTEM rule-set
			Dim j
			Dim strLabel, strNewLabel
			Dim arrPtCurrent, arrPtNext
 
			For j = 0 To ubound(arrDots)			
 
				' get current dot label
				strLabel    = rhino.TextDotText(arrDots(j))
				' get current dot location
				arrPtCurrent = rhino.TextDotPoint(arrDots(j))
				' substitute using rule set
				strNewLabel = applyStringSubstitution(strLabel)
 
				' exapnd the array of new dots
				ReDim Preserve arrNewDots(j)
 
				' make the new dot by type
				If strNewLabel="A" Then	
					arrPtNext     = Array(arrPtCurrent(0) + DISTANCE, arrPtCurrent(1), arrPtCurrent(2) ) ' RIGHT
					arrNewDots(j) = rhino.addTextDot( strNewLabel, arrPtNext )
					Call rhino.addline(arrPtCurrent, arrPtNext)
				ElseIf strNewLabel="B" Then
					arrPtNext     = Array(arrPtCurrent(0), arrPtCurrent(1) + DISTANCE, arrPtCurrent(2) ) ' UP
					arrNewDots(j) = rhino.addTextDot( strNewLabel, arrPtNext )
					Call rhino.addline(arrPtCurrent, arrPtNext)
				ElseIf strNewLabel="C" Then
					arrPtNext     = Array(arrPtCurrent(0) - DISTANCE, arrPtCurrent(1), arrPtCurrent(2) ) ' LEFT
					arrNewDots(j) = rhino.addTextDot( strNewLabel, arrPtNext )
					Call rhino.addline(arrPtCurrent, arrPtNext)
				ElseIf strNewLabel="D" Then
					arrPtNext     = Array(arrPtCurrent(0), arrPtCurrent(1) - DISTANCE, arrPtCurrent(2) ) ' DOWN
					arrNewDots(j) = rhino.addTextDot( strNewLabel, arrPtNext )
					Call rhino.addline(arrPtCurrent, arrPtNext)
				End If
 
			Next
 
 
		End If ' end generation if i > 0
		
 
	Next
 
 
End Function
 
'-----------------------------------------------CUSTOM FUNCTION -- STRING SUBSTITUTION
Function applyStringSubstitution(STRINPUT)
 
	applyStringSubstitution = Null
 
	Dim strNextGen : strNextGen = ""
 
	Dim arrCharToks : arrCharToks = rhino.strtok(STRINPUT, ",")
 
	Dim i
	For i = 0 To ubound(arrCharToks)
 
		'---- CASE A
		If arrCharToks(i) = "A" Then
			strNextGen = strNextGen + "B"
		End If
 
		'---- CASE B
		If arrCharToks(i) = "B" Then
			strNextGen = strNextGen + "A"
		End If
 
		'---- CASE C
		If arrCharToks(i) = "C" Then
			strNextGen = strNextGen + "A"
		End If
 
		'---- CASE D
		If arrCharToks(i) = "D" Then
			strNextGen = strNextGen + "B"
		End If
 
 
	Next
 
	applyStringSubstitution = strNextGen
 
 
End Function

STEP 02: Multiple String Substitutions (Bifurcation)
Similar to the previous exercise except that we allow each cell to grow multiple children.

 
Option Explicit
'Script written by maxisupermanoeuvre.com

Call LSystemAggregation()
 
Sub LSystemAggregation()
 
	' USER INOUTS
	Dim numGenerations : numGenerations = rhino.getInteger("How many GENERATIONS to run?", 5)
	Dim strInput       : strInput       = rhino.GetString("gimme starting STRING input", "A")
	Dim dblOffset      : dblOffset      = 5
 
	Call computeLSystem(strInput, numGenerations, dblOffset)
 
 
End Sub
 
'-----------------------------------------------CUSTOM RECURSIVE FUNCTION 
Function computeLSystem(STRINPUT, GENERATIONS, DISTANCE)
 
	computeLSystem = Null
 
	Dim strStartDot : strStartDot = rhino.addTextDot( STRINPUT, Array(0,0,0) )
	Dim arrDots
 
	' loop for given number of generations
	Dim i		
	For i = 0 To GENERATIONS
 
		' each time through create an array list to store all the new dots 
		If i= 0 Then
			ReDim arrNewDots(0)
			arrDots = strStartDot		
			arrNewDots(0) = strStartDot
		Else				
			arrDots = arrNewDots
			ReDim arrNewDots(-1)	
 
			' loop through characters and apply LSYSTEM rule-set
			Dim j
			Dim strLabel, strNewLabel
			Dim arrPtCurrent, arrPtNext
			Dim dotCounter, strToks
 
			dotCounter = 0
 
			For j = 0 To ubound(arrDots)			
 
				' get current dot label
				strLabel    = rhino.TextDotText(arrDots(j))
				' get current dot location
				arrPtCurrent = rhino.TextDotPoint(arrDots(j))
				' get all the characters to make
				strToks     = rhino.Strtok(strLabel, ",")
 
				' create multiple dots
				Dim k
				For k = 0 To ubound(strToks)				
 
					' exapnd the array of new dots
					ReDim Preserve arrNewDots(dotCounter)
 
					' substitute using rule set
					strNewLabel = applyStringSubstitution(strToks(k))
					Call rhino.Print("strNewLabel " & strNewLabel)
 
					' make the new dot by type
					If strToks(k)="A" Then	
						arrPtNext              = Array(arrPtCurrent(0) + DISTANCE, arrPtCurrent(1), arrPtCurrent(2) ) ' RIGHT
						arrNewDots(dotCounter) = rhino.addTextDot( strNewLabel, arrPtNext )
						Call rhino.addline(arrPtCurrent, arrPtNext)
					ElseIf strToks(k)="B" Then
						arrPtNext              = Array(arrPtCurrent(0), arrPtCurrent(1) + DISTANCE, arrPtCurrent(2) ) ' UP
						arrNewDots(dotCounter) = rhino.addTextDot( strNewLabel, arrPtNext )
						Call rhino.addline(arrPtCurrent, arrPtNext)
					ElseIf strToks(k)="C" Then
						arrPtNext              = Array(arrPtCurrent(0) - DISTANCE, arrPtCurrent(1), arrPtCurrent(2) ) ' LEFT
						arrNewDots(dotCounter) = rhino.addTextDot( strNewLabel, arrPtNext )
						Call rhino.addline(arrPtCurrent, arrPtNext)
					ElseIf strToks(k)="D" Then
						arrPtNext              = Array(arrPtCurrent(0), arrPtCurrent(1) - DISTANCE, arrPtCurrent(2) ) ' DOWN
						arrNewDots(dotCounter) = rhino.addTextDot( strNewLabel, arrPtNext )
						Call rhino.addline(arrPtCurrent, arrPtNext)
					End If
 
					' add to counter
					dotCounter = dotCounter + 1
 
				Next ' end k loop
			
			Next ' end j loop
			
		End If ' end generation if i > 0
				
	Next ' end i loop

 
End Function
 
'-----------------------------------------------CUSTOM FUNCTION -- STRING SUBSTITUTION
Function applyStringSubstitution(STRINPUT)
 
	applyStringSubstitution = Null
 
	Dim strNextGen : strNextGen = ""	
 
	'---- CASE A
	If STRINPUT = "A" Then
		strNextGen = strNextGen + "B,D"
	End If
 
	'---- CASE B
	If STRINPUT = "B" Then
		strNextGen = strNextGen + "A"
	End If
 
	'---- CASE C
	If STRINPUT = "C" Then
		strNextGen = strNextGen + "A"
	End If
 
	'---- CASE D
	If STRINPUT = "D" Then
		strNextGen = strNextGen + "A"
	End If
 
 
	applyStringSubstitution = strNextGen
 
 
End Function

EXAMPLE 01: Cell Aggregation && Growth
Here we introduce a custom function that draws a rhino poly surface cube at the location of the newly created cell.

 
Option Explicit
'Script written by maxisupermanoeuvre.com

Call LSystemAggregation()
 
Sub LSystemAggregation()
 
	' USER INOUTS
	Dim numGenerations : numGenerations = rhino.getInteger("How many GENERATIONS to run?", 5)
	Dim strInput       : strInput       = rhino.GetString("gimme starting STRING input", "A")
 
	Dim boxSizeX : boxSizeX = 5
	Dim boxSizeY : boxSizeY = 5
	Dim boxSizeZ : boxSizeZ = 5
 
	Call computeLSystem(strInput, numGenerations, boxSizeX, boxSizeY, boxSizeZ)
 
 
End Sub
 
'-----------------------------------------------CUSTOM RECURSIVE FUNCTION
Function computeLSystem(STRINPUT, GENERATIONS, SX, SY, SZ)
 
	computeLSystem = Null
 
	Dim strStartBox : strStartBox = makeCustomBox( STRINPUT, Array(0,0,0), SX, SY, SZ )
 
	Dim arrBoxes
 
	' loop for given number of generations
	Dim i		
	For i = 0 To GENERATIONS
 
		' each time through create an array list to store all the new dots 
		If i= 0 Then
			ReDim arrNewBoxes(0)
			arrBoxes       = strStartBox		
			arrNewBoxes(0) = strStartBox
		Else				
			arrBoxes = arrNewBoxes
			ReDim arrNewBoxes(-1)	
 
			' loop through characters and apply LSYSTEM rule-set
			Dim j
			Dim strInfo, strInfoToks, strLabel, strNewLabel
			Dim arrPtCurrent, arrPtNext
			Dim boxCounter, strToks
 
			boxCounter = 0
 
			For j = 0 To ubound(arrBoxes)			
 
				' get current box label
				strInfo      = rhino.objectName(arrBoxes(j))
				' split using "_" to get type_arrPointCoordinate
				strInfoToks  = rhino.Strtok(strInfo, "_")
				' get type to make
				strLabel = strInfoToks(0)
				' get current dot location
				arrPtCurrent = rhino.Str2Pt( strInfoToks(1) )
				' get all the characters to make
				strToks      = rhino.Strtok(strLabel, ",")
 
				' create multiple dots
				Dim k
				For k = 0 To ubound(strToks)				
 
					' exapnd the array of new dots
					ReDim Preserve arrNewBoxes(boxCounter)
 
					' substitute using rule set
					strNewLabel = applyStringSubstitution(strToks(k))
					'Call rhino.Print("strNewLabel " & strNewLabel)
					
					' make the new dot by type
					If strToks(k)="A" Then	
						arrPtNext               = Array(arrPtCurrent(0) + SX, arrPtCurrent(1), arrPtCurrent(2) ) ' RIGHT
						arrNewBoxes(boxCounter)  = makeCustomBox( strNewLabel, arrPtNext, SX, SY, SZ )
					ElseIf strToks(k)="B" Then
						arrPtNext               = Array(arrPtCurrent(0), arrPtCurrent(1) + SY, arrPtCurrent(2) ) ' UP
						arrNewBoxes(boxCounter) = makeCustomBox( strNewLabel, arrPtNext, SX, SY, SZ )
					ElseIf strToks(k)="C" Then
						arrPtNext               = Array(arrPtCurrent(0) - SX, arrPtCurrent(1), arrPtCurrent(2) ) ' LEFT
						arrNewBoxes(boxCounter) = makeCustomBox( strNewLabel, arrPtNext, SX, SY, SZ )
					ElseIf strToks(k)="D" Then
						arrPtNext               = Array(arrPtCurrent(0), arrPtCurrent(1) - SY, arrPtCurrent(2) + SZ) ' DOWN
						arrNewBoxes(boxCounter) = makeCustomBox( strNewLabel, arrPtNext, SX, SY, SZ )
					End If
 
					' add to counter
					boxCounter = boxCounter + 1
 
				Next ' end k loop
			
			Next ' end j loop
			
		End If ' end generation if i > 0
				
	Next ' end i loop

 
End Function
 
'-----------------------------------------------CUSTOM FUNCTION -- STRING SUBSTITUTION
Function applyStringSubstitution(STRINPUT)
 
	applyStringSubstitution = Null
 
	Dim strNextGen : strNextGen = ""	
 
	'---- CASE A
	If STRINPUT = "A" Then
		strNextGen = strNextGen + "B,D"
	End If
 
	'---- CASE B
	If STRINPUT = "B" Then
		strNextGen = strNextGen + "A"
	End If
 
	'---- CASE C
	If STRINPUT = "C" Then
		strNextGen = strNextGen + "C,B"
	End If
 
	'---- CASE D
	If STRINPUT = "D" Then
		strNextGen = strNextGen + "A,B,C"
	End If
 
 
	applyStringSubstitution = strNextGen
 
 
End Function 
 
 
Function makeCustomBox(STRINGTYPE, ARRCNTR, X, Y, Z)
 
	makeCustomBox = Null
 
	Dim arrVertices(7)
	' BOTTOM VERTICES
	arrVertices(0) = Array( ARRCNTR(0)-X/2, ARRCNTR(1)+Y/2, ARRCNTR(2)-Z/2 )
	arrVertices(1) = Array( ARRCNTR(0)+X/2, ARRCNTR(1)+Y/2, ARRCNTR(2)-Z/2 )
	arrVertices(2) = Array( ARRCNTR(0)+X/2, ARRCNTR(1)-Y/2, ARRCNTR(2)-Z/2 )
	arrVertices(3) = Array( ARRCNTR(0)-X/2, ARRCNTR(1)-Y/2, ARRCNTR(2)-Z/2 )
	' TOP VERTICES
	arrVertices(4) = Array( ARRCNTR(0)-X/2, ARRCNTR(1)+Y/2, ARRCNTR(2)+Z/2 )
	arrVertices(5) = Array( ARRCNTR(0)+X/2, ARRCNTR(1)+Y/2, ARRCNTR(2)+Z/2 )
	arrVertices(6) = Array( ARRCNTR(0)+X/2, ARRCNTR(1)-Y/2, ARRCNTR(2)+Z/2 )
	arrVertices(7) = Array( ARRCNTR(0)-X/2, ARRCNTR(1)-Y/2, ARRCNTR(2)+Z/2 )
 
	Dim strBox : strBox = rhino.addBox(arrVertices)
	Call rhino.ObjectName(strBox, STRINGTYPE & "_" & rhino.Pt2Str(ARRCNTR) )
 
	makeCustomBox = strBox	
 
End Function

Computing Neighbourhoods — Cellular Automata

iainmaxwell — Tue, 31 Aug 2010 09:27:45 +0000

CELLULAR AUTOMATA
A cellular automaton (pl. cellular automata, abbrev. CA) is a discrete model studied in computability theory, mathematics, physics, complexity science, theoretical biology and microstructure modeling. It consists of a regular grid of cells, each in one of a finite number of states, such as “On” and “Off” (in contrast to a coupled map lattice). The grid can be in any finite number of dimensions. For each cell, a set of cells called its neighborhood (usually including the cell itself) is defined relative to the specified cell. For example, the neighborhood of a cell might be defined as the set of cells a distance of 2 or less from the cell. An initial state (time t=0) is selected by assigning a state for each cell. A new generation is created (advancing t by 1), according to some fixed rule (generally, a mathematical function) that determines the new state of each cell in terms of the current state of the cell and the states of the cells in its neighborhood. For example, the rule might be that the cell is “On” in the next generation if exactly two of the cells in the neighborhood are “On” in the current generation, otherwise the cell is “Off” in the next generation. Typically, the rule for updating the state of cells is the same for each cell and does not change over time, and is applied to the whole grid simultaneously, though exceptions are known.

Further reading:
How Simple Programs Behave – Stephen Wolfram
WIKI

STEP 01: Applying the rules

 
Option Explicit
'Script written by maxi@supermanoeuvre.com

Call BerlinCA()
 
Sub BerlinCA()
 
	Dim strInput : strInput = rhino.GetString("gimme input STRING", "0,0,0,1,0,0,1,1,0,1,1,1,1,1" )	
 
	Call rhino.print("the input string to test: " & strInput)
	Call rhino.print("the result of rule 30 is: " & applyRule30(strInput) )
 
 
End Sub
 
'--------------------------------------------------------- CUSTOM FUNCTION -- THE RULE SET 30
Function applyRule30(STRINPUT)
 
	applyRule30 = Null
 
	Dim arrTokens, strCharCurrent, strCharLeft, strCharRight, strNextGen
 
	strNextGen = ""
	arrTokens = Rhino.Strtok (STRINPUT, ",")
 
	Dim i
	For i = 0 To ubound(arrTokens)
 
		'------------------------GET LEFT SIDE (PREVIOUS COUNTER STEP)
		If Not i = 0 Then
			strCharLeft = arrTokens(i-1)
		Else
			strCharLeft = arrTokens(ubound(arrTokens))
		End If
 
		'------------------------GET CURRENT
		strCharCurrent = arrTokens(i)
 
		'------------------------GET RIGHT (NEXT COUNTER STEP)		
		If Not i = ubound(arrTokens) Then
			strCharRight = arrTokens(i+1)
		Else
			strCharRight = arrTokens(0)
		End If	
 
 
		'------------------------THE CA RULE 30		
		'---- CONDITION #01
		If strCharLeft="1" And strCharCurrent="1" And strCharRight="1" Then
			If i = 0 Then
				strNextGen = strNextGen & "0"
			Else
				strNextGen = strNextGen & "," & "0"
			End If
		End If
 
		'---- CONDITION #02
		If strCharLeft="1" And strCharCurrent="1" And strCharRight="0" Then
			If i = 0 Then
				strNextGen = strNextGen & "0"
			Else
				strNextGen = strNextGen & "," & "0"
			End If
		End If
 
		'---- CONDITION #03
		If strCharLeft="1" And strCharCurrent="0" And strCharRight="1" Then
			If i = 0 Then
				strNextGen = strNextGen & "0"
			Else
				strNextGen = strNextGen & "," & "0"
			End If
		End If
 
		'---- CONDITION #04
		If strCharLeft="1" And strCharCurrent="0" And strCharRight="0" Then
			If i = 0 Then
				strNextGen = strNextGen & "1"
			Else
				strNextGen = strNextGen & "," & "1"
			End If
		End If
 
		'---- CONDITION #05
		If strCharLeft="0" And strCharCurrent="1" And strCharRight="1" Then
			If i = 0 Then
				strNextGen = strNextGen & "1"
			Else
				strNextGen = strNextGen & "," & "1"
			End If
		End If
 
		'---- CONDITION #06
		If strCharLeft="0" And strCharCurrent="1" And strCharRight="0" Then
			If i = 0 Then
				strNextGen = strNextGen & "1"
			Else
				strNextGen = strNextGen & "," & "1"
			End If
		End If
 
		'---- CONDITION #07
		If strCharLeft="0" And strCharCurrent="0" And strCharRight="1" Then
			If i = 0 Then
				strNextGen = strNextGen & "1"
			Else
				strNextGen = strNextGen & "," & "1"
			End If
		End If
 
		'---- CONDITION #08
		If strCharLeft="0" And strCharCurrent="0" And strCharRight="0" Then
			If i = 0 Then
				' Starting value
				strNextGen = strNextGen & "0"
			Else
				' separate with a comma
				strNextGen = strNextGen & "," & "0"
			End If
		End If
 
	Next
 
	applyRule30 = strNextGen
 
End Function

EXAMPLE 01: State-based Text Dots
In this example we visualize the CA states by placing a rhino text dot indicating the location, and whether the cell is active or not.

 
Option Explicit
'Script written by maxi@supermanoeuvre.com

Call BerlinCA()
 
Sub BerlinCA()
 
	' USER INOUTS
	Dim numGenerations : numGenerations = rhino.getInteger("How many GENERATIONS to run?", 50)
	Dim strInput       : strInput       = rhino.GetString("gimme input string ---separated by comma---", "0,0,0,1,0,0,1,1,0,1,1,1,1,1")
 
	Call computeCA(strInput, numGenerations)
 
End Sub
 
'--------------------------------------------------------- CUSTOM FUNCTION -- COMPUTE THE CA
Function computeCA(STRINPUT, GENERATIONS)
 
	computeCA = Null
 
	' string of characters
	Dim strGen : strGen = STRINPUT
 
 
	Dim i
 
	' loop for given number of generations
	For i = 0 To GENERATIONS
 
		Dim arrChars : arrChars = Rhino.Strtok (strGen, ",")
 
		' loop through characters and apply CA rule-set
		Dim j
		For j = 0 To ubound(arrChars)
 
			Dim strDot : strDot = rhino.addTextDot(arrChars(j), Array(j,i,0) )
 
			If arrChars(j)="0" Then
				' OFF is white
				Call Rhino.ObjectColor (strDot , RGB(255,255,255))
			Else
				' ON is black
				Call Rhino.ObjectColor (strDot , RGB(0,0,0))
			End If
 
		Next
 
		strGen = applyRule30(strGen)
 
	Next
 
 
End Function
 
'--------------------------------------------------------- CUSTOM FUNCTION -- THE RULE SET 30
Function applyRule30(STRINPUT)
 
	applyRule30 = Null
 
	Dim arrTokens, strCharCurrent, strCharLeft, strCharRight, strNextGen
 
	strNextGen = ""
	arrTokens = Rhino.Strtok (STRINPUT, ",")
 
	Dim i
	For i = 0 To ubound(arrTokens)
 
		'------------------------GET LEFT SIDE (PREVIOUS COUNTER STEP)
		If Not i = 0 Then
			strCharLeft = arrTokens(i-1)
		Else
			strCharLeft = arrTokens(ubound(arrTokens))
		End If
 
		'------------------------GET CURRENT
		strCharCurrent = arrTokens(i)
 
		'------------------------GET RIGHT (NEXT COUNTER STEP)		
		If Not i = ubound(arrTokens) Then
			strCharRight = arrTokens(i+1)
		Else
			strCharRight = arrTokens(0)
		End If	
 
 
		'------------------------THE CA RULE 30		
		'---- CONDITION #01
		If strCharLeft="1" And strCharCurrent="1" And strCharRight="1" Then
			If i = 0 Then
				strNextGen = strNextGen & "0"
			Else
				strNextGen = strNextGen & "," & "0"
			End If
		End If
 
		'---- CONDITION #02
		If strCharLeft="1" And strCharCurrent="1" And strCharRight="0" Then
			If i = 0 Then
				strNextGen = strNextGen & "0"
			Else
				strNextGen = strNextGen & "," & "0"
			End If
		End If
 
		'---- CONDITION #03
		If strCharLeft="1" And strCharCurrent="0" And strCharRight="1" Then
			If i = 0 Then
				strNextGen = strNextGen & "0"
			Else
				strNextGen = strNextGen & "," & "0"
			End If
		End If
 
		'---- CONDITION #04
		If strCharLeft="1" And strCharCurrent="0" And strCharRight="0" Then
			If i = 0 Then
				strNextGen = strNextGen & "1"
			Else
				strNextGen = strNextGen & "," & "1"
			End If
		End If
 
		'---- CONDITION #05
		If strCharLeft="0" And strCharCurrent="1" And strCharRight="1" Then
			If i = 0 Then
				strNextGen = strNextGen & "1"
			Else
				strNextGen = strNextGen & "," & "1"
			End If
		End If
 
		'---- CONDITION #06
		If strCharLeft="0" And strCharCurrent="1" And strCharRight="0" Then
			If i = 0 Then
				strNextGen = strNextGen & "1"
			Else
				strNextGen = strNextGen & "," & "1"
			End If
		End If
 
		'---- CONDITION #07
		If strCharLeft="0" And strCharCurrent="0" And strCharRight="1" Then
			If i = 0 Then
				strNextGen = strNextGen & "1"
			Else
				strNextGen = strNextGen & "," & "1"
			End If
		End If
 
		'---- CONDITION #08
		If strCharLeft="0" And strCharCurrent="0" And strCharRight="0" Then
			If i = 0 Then
				' Starting value
				strNextGen = strNextGen & "0"
			Else
				' separate with a comma
				strNextGen = strNextGen & "," & "0"
			End If
		End If
 
	Next
 
	applyRule30 = strNextGen
 
End Function

EXAMPLE 02: State-based Cube Distribution
In this example we add another custom function which creates a poly surface box indicating the location, and whether the cell is active or not.
We also introduce rule set 110.

 
Option Explicit
'Script written by maxi@supermanoeuvre.com

Call BerlinCA()
 
Sub BerlinCA()
 
 
	Dim numGenerations : numGenerations = rhino.getInteger("How many GENERATIONS to run?", 35)
	If isNull(numGenerations) Then Exit Sub
 
	Dim strInput       : strInput       = rhino.GetString("gimme input string ---separated by comma---", "0,0,0,1,0,0,1,0,0,1,0,1,0,1")
	If isNull(strInput) Then Exit Sub
 
	Dim boxSizeX : boxSizeX = 5
	Dim boxSizeY : boxSizeY = 5
	Dim boxSizeZ : boxSizeZ = 5
 
	Call rhino.addLayer( "VOID", RGB(255,255,255) )
	Call rhino.addLayer( "SOLID", RGB(145,0,245) )
 
	Call rhino.EnableRedraw(False)
	Call computeCA(strInput, numGenerations, boxSizeX, boxSizeY, boxSizeZ )
	Call rhino.EnableRedraw(True)
 
End Sub
 
'--------------------------------------------------------- CUSTOM FUNCTION -- COMPUTE THE CA
Function computeCA(STRINPUT, GENERATIONS, SX, SY, SZ)
 
	computeCA = Null
 
	' string of characters
	Dim strGen : strGen = STRINPUT
 
 
	Dim i
 
	' loop for given number of generations
	For i = 0 To GENERATIONS
 
		Dim arrChars : arrChars = Rhino.Strtok (strGen, ",")
 
		' loop through characters and apply CA rule-set
		Dim j
		For j = 0 To ubound(arrChars)
 
			Dim strBox : strBox = makeBox(arrChars(j), Array(j*SX,i*SY,0), SX, SY, SZ )		
 
		Next
 
		'strGen = applyRule30(strGen)
		strGen = applyRule110(strGen)
 
	Next
 
 
End Function
 
'--------------------------------------------------------- CUSTOM FUNCTION -- THE RULE SET 30
Function applyRule30(STRINPUT)
 
	applyRule30 = Null
 
	Dim arrTokens, strCharCurrent, strCharLeft, strCharRight, strNextGen
 
	strNextGen = ""
	arrTokens = Rhino.Strtok (STRINPUT, ",")
 
	Dim i
	For i = 0 To ubound(arrTokens)
 
		'------------------------GET LEFT SIDE (PREVIOUS COUNTER STEP)
		If Not i = 0 Then
			strCharLeft = arrTokens(i-1)
		Else
			strCharLeft = arrTokens(ubound(arrTokens))
		End If
 
		'------------------------GET CURRENT
		strCharCurrent = arrTokens(i)
 
		'------------------------GET RIGHT (NEXT COUNTER STEP)		
		If Not i = ubound(arrTokens) Then
			strCharRight = arrTokens(i+1)
		Else
			strCharRight = arrTokens(0)
		End If	
 
 
		'------------------------THE CA RULE 30		
		'---- CONDITION #01
		If strCharLeft="1" And strCharCurrent="1" And strCharRight="1" Then
			If i = 0 Then
				strNextGen = strNextGen & "0"
			Else
				strNextGen = strNextGen & "," & "0"
			End If
		End If
 
		'---- CONDITION #02
		If strCharLeft="1" And strCharCurrent="1" And strCharRight="0" Then
			If i = 0 Then
				strNextGen = strNextGen & "0"
			Else
				strNextGen = strNextGen & "," & "0"
			End If
		End If
 
		'---- CONDITION #03
		If strCharLeft="1" And strCharCurrent="0" And strCharRight="1" Then
			If i = 0 Then
				strNextGen = strNextGen & "0"
			Else
				strNextGen = strNextGen & "," & "0"
			End If
		End If
 
		'---- CONDITION #04
		If strCharLeft="1" And strCharCurrent="0" And strCharRight="0" Then
			If i = 0 Then
				strNextGen = strNextGen & "1"
			Else
				strNextGen = strNextGen & "," & "1"
			End If
		End If
 
		'---- CONDITION #05
		If strCharLeft="0" And strCharCurrent="1" And strCharRight="1" Then
			If i = 0 Then
				strNextGen = strNextGen & "1"
			Else
				strNextGen = strNextGen & "," & "1"
			End If
		End If
 
		'---- CONDITION #06
		If strCharLeft="0" And strCharCurrent="1" And strCharRight="0" Then
			If i = 0 Then
				strNextGen = strNextGen & "1"
			Else
				strNextGen = strNextGen & "," & "1"
			End If
		End If
 
		'---- CONDITION #07
		If strCharLeft="0" And strCharCurrent="0" And strCharRight="1" Then
			If i = 0 Then
				strNextGen = strNextGen & "1"
			Else
				strNextGen = strNextGen & "," & "1"
			End If
		End If
 
		'---- CONDITION #08
		If strCharLeft="0" And strCharCurrent="0" And strCharRight="0" Then
			If i = 0 Then
				' Starting value
				strNextGen = strNextGen & "0"
			Else
				' separate with a comma
				strNextGen = strNextGen & "," & "0"
			End If
		End If
 
	Next
 
	applyRule30 = strNextGen
 
End Function
 
'--------------------------------------------------------- CUSTOM FUNCTION -- THE RULE SET 30
Function applyRule110(STRINPUT)
 
	applyRule110 = Null
 
	Dim arrTokens, strCharCurrent, strCharLeft, strCharRight, strNextGen
 
	strNextGen = ""
	arrTokens = Rhino.Strtok (STRINPUT, ",")
 
	Dim i
	For i = 0 To ubound(arrTokens)
 
		'------------------------GET LEFT SIDE (PREVIOUS COUNTER STEP)
		If Not i = 0 Then
			strCharLeft = arrTokens(i-1)
		Else
			strCharLeft = arrTokens(ubound(arrTokens))
		End If
 
		'------------------------GET CURRENT
		strCharCurrent = arrTokens(i)
 
		'------------------------GET RIGHT (NEXT COUNTER STEP)		
		If Not i = ubound(arrTokens) Then
			strCharRight = arrTokens(i+1)
		Else
			strCharRight = arrTokens(0)
		End If	
 
 
		'------------------------THE CA RULE 110		
		'---- CONDITION #01
		If strCharLeft="1" And strCharCurrent="1" And strCharRight="1" Then
			If i = 0 Then
				strNextGen = strNextGen & "0"
			Else
				strNextGen = strNextGen & "," & "0"
			End If
		End If
 
		'---- CONDITION #02
		If strCharLeft="1" And strCharCurrent="1" And strCharRight="0" Then
			If i = 0 Then
				strNextGen = strNextGen & "1"
			Else
				strNextGen = strNextGen & "," & "1"
			End If
		End If
 
		'---- CONDITION #03
		If strCharLeft="1" And strCharCurrent="0" And strCharRight="1" Then
			If i = 0 Then
				strNextGen = strNextGen & "1"
			Else
				strNextGen = strNextGen & "," & "1"
			End If
		End If
 
		'---- CONDITION #04
		If strCharLeft="1" And strCharCurrent="0" And strCharRight="0" Then
			If i = 0 Then
				strNextGen = strNextGen & "0"
			Else
				strNextGen = strNextGen & "," & "0"
			End If
		End If
 
		'---- CONDITION #05
		If strCharLeft="0" And strCharCurrent="1" And strCharRight="1" Then
			If i = 0 Then
				strNextGen = strNextGen & "1"
			Else
				strNextGen = strNextGen & "," & "1"
			End If
		End If
 
		'---- CONDITION #06
		If strCharLeft="0" And strCharCurrent="1" And strCharRight="0" Then
			If i = 0 Then
				strNextGen = strNextGen & "1"
			Else
				strNextGen = strNextGen & "," & "1"
			End If
		End If
 
		'---- CONDITION #07
		If strCharLeft="0" And strCharCurrent="0" And strCharRight="1" Then
			If i = 0 Then
				strNextGen = strNextGen & "1"
			Else
				strNextGen = strNextGen & "," & "1"
			End If
		End If
 
		'---- CONDITION #08
		If strCharLeft="0" And strCharCurrent="0" And strCharRight="0" Then
			If i = 0 Then
				' Starting value
				strNextGen = strNextGen & "0"
			Else
				' separate with a comma
				strNextGen = strNextGen & "," & "0"
			End If
		End If
 
	Next
 
	applyRule110 = strNextGen	
 
End Function
 
 
Function makeBox(ID, ARRCNTR, X, Y, Z)
 
	makeBox = Null
 
	Dim arrVertices(7)
	' BOTTOM VERTICES
	arrVertices(0) = Array( ARRCNTR(0)-X/2, ARRCNTR(1)+Y/2, ARRCNTR(2)-Z/2 )
	arrVertices(1) = Array( ARRCNTR(0)+X/2, ARRCNTR(1)+Y/2, ARRCNTR(2)-Z/2 )
	arrVertices(2) = Array( ARRCNTR(0)+X/2, ARRCNTR(1)-Y/2, ARRCNTR(2)-Z/2 )
	arrVertices(3) = Array( ARRCNTR(0)-X/2, ARRCNTR(1)-Y/2, ARRCNTR(2)-Z/2 )
	' TOP VERTICES
	arrVertices(4) = Array( ARRCNTR(0)-X/2, ARRCNTR(1)+Y/2, ARRCNTR(2)+Z/2 )
	arrVertices(5) = Array( ARRCNTR(0)+X/2, ARRCNTR(1)+Y/2, ARRCNTR(2)+Z/2 )
	arrVertices(6) = Array( ARRCNTR(0)+X/2, ARRCNTR(1)-Y/2, ARRCNTR(2)+Z/2 )
	arrVertices(7) = Array( ARRCNTR(0)-X/2, ARRCNTR(1)-Y/2, ARRCNTR(2)+Z/2 )
 
	Dim strBox
	strBox = rhino.addBox(arrVertices)
 
	If ID="0" Then
		' OFF is white
		Call Rhino.ObjectLayer (strBox , "VOID")
	Else
		' ON is black
		Call Rhino.ObjectLayer (strBox , "SOLID")
	End If
 
	makeBox = strBox	
 
End Function